Dim strPrevControl As String           'משתנה המחזיק את הכפתור האחרון שהוחלף
Dim strPrevControlPicture As String    'מחזיק את התמונה של הכפתור האחרון שהוחלף

Private Sub ChangePicture(strControlName As String, strNewPicPath As String)
    'אם יש בזכרון פקד קודם שהחלפנו אז תחליף אותו חזרה לתמונה הישנה
    If strPrevControl <> "" Then
        With Me(strPrevControl)
            'כמובן שצריך להחילף רק אם הוא עוד לא הוחלף
            If .Picture <> strPrevControlPicture Then .Picture = strPrevControlPicture
        End With
    End If
    
    'נשמור את הפקד שאנחנו מחליפים עכשיו
    strPrevControl = strControlName
    
    'עכשיו נבצע את ההחלפה
    With Me(strControlName)
        'קודם נשמור את שם התמונה הקודם
        strPrevControlPicture = .Picture
        'ועכשיו נחליף אם צריך
        If .Picture <> strNewPicPath Then .Picture = strNewPicPath
    End With
End Sub

Private Sub ReturnPictureToNormal()
    'זוהי פונקציה להחזרת התמונה הקודמת לפקד אם צריך
    If strPrevControl <> "" Then
        With Me(strPrevControl)
            If .Picture <> strPrevControlPicture Then .Picture = strPrevControlPicture
        End With
    End If
End Sub

'זה הארוע של תזוזת עכבר מעל שטח ה
'DETAIL
'של הטופס ובו אנחנו פשוט קוראים להחזיר את הפקד האחרון למצבו הקודם
Private Sub Detail_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    Call ReturnPictureToNormal
End Sub

'זהו הארוע של כפתור
'COMMAND1
Private Sub Command1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    'נקרא לפונקציה עם שם הפקד שלנו ועם הקובץ של התמונה החדשה
    Call ChangePicture("Command1", "c:\balloon.bmp")
End Sub

'זהו הארוע של כפתור
'COMMAND2
Private Sub Command2_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    'נקרא לפונקציה עם שם הפקד שלנו ועם הקובץ של התמונה החדשה
    Call ChangePicture("Command2", "c:\ball.bmp")
End Sub